« 新技術:TCPに代わるQUIC(Quick UDP Internet Connections) | トップページ | gnuplotでグラフが正しく描画されてないように思える場合 »

2018年5月 4日 (金)

個人的gnuplot用スクリプトその2

024

〜 gnuplot5.0にて作成 〜
〔関数グラフ用〕
 【loadコマンド用スクリプト】10 x 10グラフ

# gnuplot5 load用
a1=10 #表示領域の変数設定:x軸の正の方向
a2=10 #表示領域の変数設定:y軸の正の方向
a3=-10 #表示領域の変数設定:x軸方向の負の方向
a4=-10 #表示領域の変数設定:y軸の負の方向
############ 各種設定値
## ラインの太さ関係
line_grid=0.5            # グリッド線の太さ
line_axis=1.8            # 軸の太さ
line_Outer_frame = 1.3        # 外枠の太さ
line_fx = 1.3            # 関数の線の太さ
## ラベルの位置
position_fontx_x = a1 + 0.4    # 文字xの位置
position_fontx_y = 0.15
position_fonty_x = -0.47    # 文字yの位置
position_fonty_y = a2 +1.2
position_fontO_x = -1.1    # 文字Oの位置
position_fontO_y = - 0.8
## 軸のメモリ値の位置
position_inty_x = 0.2        # y軸のメモリ値の位置
position_inty_y = 0.005
position_intx_x = 0.15        # x軸のメモリ値の位置
position_intx_y = 0.005
############### 設定値終わり
unset key       # 凡例の非表示
set zeroaxis    # 軸を中央に
set zeroaxis lt -1 lw line_axis # 座標軸設定 lt はカラー lw は線の太さ
set xtics axis  # 軸の値を中央に
set ytics axis
set x2tics axis
set y2tics axis
set format x2 ""    # 軸の値2を非表示
set format y2 ""
set x2tics 1        # グリッドを1メモリずつに
set y2tics 1
set size ratio -1   # 縦横の比率を1:1に
set xtics ('-12' -12 ,'-8' -8 ,'' 0, '-4' -4, '4' 4 ,'8' 8 , '12' 12)
set ytics ('-12' -12 ,'-8' -8 ,'' 0, '-4' -4, '4' 4 ,'8' 8 , '12' 12)
set grid x2tics lt -1 lw line_grid # グリッドの線の色・太さ
set grid y2tics lt -1 lw line_grid
set grid lc rgbcolor "black"
set grid noxtics x2tics noytics y2tics
set tics scale 0    # 軸メモリのカット
set style line 1 lc rgbcolor "black" lw line_fx
set xrange [a3:a1]
set yrange [a4:a2]
# ↓ size character 矢印の頭の部分の大きさと角度の指定。「頭の大きさは文字の1.2倍の大きさで、先端の角度は20度」など
set style arrow 2 size character 1.2,20 filled nohead lw line_axis

# 軸を矢印化するなら下の行を有効に(行の頭の#を外す & 上の行を無効化に)
#set style arrow 2 size character 1.5,20 filled lw 2   

set arrow 1 from a3,0 to a1,0 lw 5.0 arrowstyle 2
set arrow 2 from 0,a4 to 0,a2 lw 5.0 arrowstyle 2
set xtics offset position_intx_x , graph position_intx_y
###文字ラベル(X,Y,O)が不要ならば、以下の赤文字の3行は削除
set label 1 at first position_fontx_x,position_fontx_y "x" font 'Century Schoolbook L:Italic,25'
set label 2 at first position_fonty_x,position_fonty_y "y" font 'Century Schoolbook L:Italic,25'
set label 3 at first position_fontO_x,position_fontO_y "O" font 'Century Schoolbook L,18'

set tics font "Century Schoolbook L,17"
set ytics offset position_inty_x , graph position_inty_y
set border 15 lt -1 lw line_Outer_frame # 外枠の設定 > 15は左右上下の設定となる
set tmargin 3.5 #上方のマージン y 軸文字用
set bmargin 2    # 下マージン

上記をエディタにコピペして保存。(赤字のところは任意で変更可。)

001_r  002_r_2

保存場所はLinuxの場合はホームディレクトリ。
Windowsの場合は「gnuplot スクリプトの保存先(Windows:MinGW版)」を参考に。
 
あとは、gnuplotを起動して、このスクリプトをloadすれば良い。
 
今回は保存ファイル名を「gpls_10x10.txt」としたので、

load "./gpls_10x10.txt" (load "gpls_10x10.txt" でも可。「./」はカレントディレクトリを意味する。)

と入力し、あとは好きな関数をプロットすれば終了。

024_2  

※ このスクリプト使用時において「plot 関数 ls 1」とすることで、関数が黒色になる。
これは、LineStyle 1 (ls 1) にて黒色設定をしているため。
「ls 1」を抜くと、黒色で表示されないので注意。
 
025

026  
(スクリプトを「a2 = 15」「a4 = -5」に書き換えて使用。)

 
 
 
 

〔関連ページ〕 
gnuplot で比例・反比例・放物線のグラフの作成 
gnuplotで定義域(変域)のあるグラフの作成 
gnuplot でヒストグラム・度数分布多角形づくり  
gnuplot フォント関係 with Linux  

 
 
 
 
 
 

« 新技術:TCPに代わるQUIC(Quick UDP Internet Connections) | トップページ | gnuplotでグラフが正しく描画されてないように思える場合 »

gnuplot」カテゴリの記事

2021年5月
            1
2 3 4 5 6 7 8
9 10 11 12 13 14 15
16 17 18 19 20 21 22
23 24 25 26 27 28 29
30 31          
無料ブログはココログ